// Minimap and stats
extend Class SWWMStatusBar
{
	// quicksort (player scores)
	private int partition_playerscore( Array<PlayerInfo> a, int l, int h )
	{
		PlayerInfo pv = a[h];
		int i = (l-1);
		for ( int j=l; j<=(h-1); j++ )
		{
			if ( pv.fragcount < a[j].fragcount )
			{
				i++;
				PlayerInfo tmp = a[j];
				a[j] = a[i];
				a[i] = tmp;
			}
		}
		PlayerInfo tmp = a[h];
		a[h] = a[i+1];
		a[i+1] = tmp;
		return i+1;
	}
	private void qsort_playerscore( Array<PlayerInfo> a, int l, int h )
	{
		if ( l >= h ) return;
		int p = partition_playerscore(a,l,h);
		qsort_playerscore(a,l,p-1);
		qsort_playerscore(a,p+1,h);
	}

	private void FlushTopStuff()
	{
		ScoreInter.Reset(SWWMCredits.Get(CPlayer));
	}

	private void TickTopStuffInterpolators()
	{
		ScoreInter.Update(SWWMCredits.Get(CPlayer));
		// stats flashing
		if ( level.killed_monsters > oldkills )
		{
			oldkills = level.killed_monsters;
			killflash = gametic+25;
		}
		if ( level.found_items > olditems )
		{
			olditems = level.found_items;
			itemflash = gametic+25;
		}
		if ( level.found_secrets > oldsecrets )
		{
			oldsecrets = level.found_secrets;
			secretflash = gametic+25;
		}
		if ( level.total_monsters > oldtkills )
		{
			oldtkills = level.total_monsters;
			tkillflash = gametic+25;
		}
		if ( level.total_items > oldtitems )
		{
			oldtitems = level.total_items;
			titemflash = gametic+25;
		}
		if ( level.total_secrets > oldtsecrets )
		{
			oldtsecrets = level.total_secrets;
			tsecretflash = gametic+25;
		}
		// purge expired key flashes
		for ( int i=0; i<keyflash.Size(); i++ )
		{
			if ( keyflash[i].flashtime >= gametic ) continue;
			keyflash.Delete(i--);
		}
		// minimap zoom interpolation
		double desiredzoom = clamp(swwm_mm_zoom,.5,level.allmap?2.:1.);
		if ( (minimapzoom != swwm_mm_zoom) || (oldminimapzoom != swwm_mm_zoom) )
		{
			oldminimapzoom = minimapzoom;
			double diff = .1*(desiredzoom-minimapzoom);
			minimapzoom += diff;
			if ( abs(minimapzoom-desiredzoom) <= .01 )
				minimapzoom = desiredzoom;
		}
	}

	private void TickTopStuff()
	{
		// deathmatch stuff
		if ( !deathmatch ) return;
		if ( teamplay )
		{
			if ( teamactive.Size() != Teams.Size() ) teamactive.Resize(Teams.Size());
			if ( teamscore.Size() != Teams.Size() ) teamscore.Resize(Teams.Size());
			for ( int i=0; i<Teams.Size(); i++ )
			{
				teamactive[i] = false;
				teamscore[i] = 0;
			}
			for ( int i=0; i<MAXPLAYERS; i++ )
			{
				if ( !playeringame[i] ) continue;
				int team = players[i].GetTeam();
				if ( team != -1 )
				{
					teamactive[team] = true;
					teamscore[team] += players[i].fragcount;
				}
			}
			return;
		}
		playercount = 0;
		int highscore = int.min;
		tiedscore = false;
		rank = 1;
		for ( int i=0; i<MAXPLAYERS; i++ )
		{
			if ( !playeringame[i] ) continue;
			playercount++;
			if ( players[i] == CPlayer ) continue;
			if ( players[i].fragcount > CPlayer.fragcount )
				rank += 1;
			else if ( players[i].fragcount == CPlayer.fragcount )
				tiedscore = true;
			if ( players[i].fragcount > highscore )
				highscore = players[i].fragcount;
		}
		if ( sortplayers.Size() != playercount ) sortplayers.Resize(playercount);
		for ( int i=0, j=0; i<MAXPLAYERS; i++ )
		{
			if ( !playeringame[i] ) continue;
			sortplayers[j++] = players[i];
		}
		// sort players by score
		qsort_playerscore(sortplayers,0,playercount-1);
		if ( playercount <= 1 ) highscore = CPlayer.fragcount;
		lead = CPlayer.fragcount-highscore;
	}

	// minimap helper code
	private void GetMinimapColors()
	{
		mm_colorset = swwm_mm_colorset;
		switch ( mm_colorset )
		{
		case 1:
			// gzdoom
			mm_backcolor = am_backcolor;
			mm_cdwallcolor = am_cdwallcolor;
			mm_efwallcolor = am_efwallcolor;
			mm_fdwallcolor = am_fdwallcolor;
			mm_interlevelcolor = am_interlevelcolor;
			mm_intralevelcolor = am_intralevelcolor;
			mm_lockedcolor = am_lockedcolor;
			mm_notseencolor = am_notseencolor;
			mm_portalcolor = am_portalcolor;
			mm_secretsectorcolor = am_secretsectorcolor;
			mm_secretwallcolor = am_secretwallcolor;
			mm_specialwallcolor = am_specialwallcolor;
			mm_thingcolor = am_thingcolor;
			mm_thingcolor_citem = am_thingcolor_citem;
			mm_thingcolor_friend = am_thingcolor_friend;
			mm_thingcolor_item = am_thingcolor_item;
			mm_thingcolor_monster = am_thingcolor_monster;
			mm_thingcolor_ncmonster = am_thingcolor_ncmonster;
			mm_thingcolor_shootable = am_thingcolor;
			mm_thingcolor_vipitem = am_unexploredsecretcolor;
			mm_thingcolor_missile = am_specialwallcolor;
			mm_tswallcolor = am_tswallcolor;
			mm_unexploredsecretcolor = am_unexploredsecretcolor;
			mm_wallcolor = am_wallcolor;
			mm_yourcolor = am_yourcolor;
			mm_displaylocks = true;
			break;
		case 2:
			// doom
			mm_backcolor = "00 00 00";
			mm_cdwallcolor = "fc fc 00";
			mm_efwallcolor = "bc 78 48";
			mm_fdwallcolor = "bc 78 48";
			mm_interlevelcolor = 0;
			mm_intralevelcolor = 0;
			mm_lockedcolor = "fc fc 00";
			mm_notseencolor = "6c 6c 6c";
			mm_portalcolor = "40 40 40";
			mm_secretsectorcolor = 0;
			mm_secretwallcolor = 0;
			mm_specialwallcolor = 0;
			mm_thingcolor = "74 fc 6c";
			mm_thingcolor_citem = "74 fc 6c";
			mm_thingcolor_friend = "74 fc 6c";
			mm_thingcolor_item = "74 fc 6c";
			mm_thingcolor_monster = "74 fc 6c";
			mm_thingcolor_ncmonster = "74 fc 6c";
			mm_thingcolor_shootable = "74 fc 6c";
			mm_thingcolor_vipitem = "74 fc 6c";
			mm_thingcolor_missile = "74 fc 6c";
			mm_tswallcolor = "80 80 80";
			mm_unexploredsecretcolor = 0;
			mm_wallcolor = "fc 00 00";
			mm_yourcolor = "ff ff ff";
			mm_displaylocks = false;
			break;
		case 3:
			// strife
			mm_backcolor = "00 00 00";
			mm_cdwallcolor = "77 73 73";
			mm_efwallcolor = "37 3b 5b";
			mm_fdwallcolor = "37 3b 5b";
			mm_interlevelcolor = 0;
			mm_intralevelcolor = 0;
			mm_lockedcolor = "77 73 73";
			mm_notseencolor = "6c 6c 6c";
			mm_portalcolor = "40 40 40";
			mm_secretsectorcolor = 0;
			mm_secretwallcolor = 0;
			mm_specialwallcolor = 0;
			mm_thingcolor = "bb 3b 00";
			mm_thingcolor_citem = "db ab 00";
			mm_thingcolor_friend = "fc 00 00";
			mm_thingcolor_item = "db ab 00";
			mm_thingcolor_monster = "fc 00 00";
			mm_thingcolor_ncmonster = "fc 00 00";
			mm_thingcolor_shootable = "bb 3b 00";
			mm_thingcolor_vipitem = "db ab 00";
			mm_thingcolor_missile = "bb 3b 00";
			mm_tswallcolor = "77 73 73";
			mm_unexploredsecretcolor = 0;
			mm_wallcolor = "c7 ce ce";
			mm_yourcolor = "ef ef ef";
			mm_displaylocks = false;
			break;
		case 4:
			// raven
			mm_backcolor = "6c 54 40";
			mm_cdwallcolor = "67 3b 1f";
			mm_efwallcolor = "d0 b0 85";
			mm_fdwallcolor = "d0 b0 85";
			mm_interlevelcolor = 0;
			mm_intralevelcolor = 0;
			mm_lockedcolor = "67 3b 1f";
			mm_notseencolor = "00 00 00";
			mm_portalcolor = "50 50 50";
			mm_secretsectorcolor = 0;
			mm_secretwallcolor = 0;
			mm_specialwallcolor = 0;
			mm_thingcolor = "ec ec ec";
			mm_thingcolor_citem = "ec ec ec";
			mm_thingcolor_friend = "ec ec ec";
			mm_thingcolor_item = "ec ec ec";
			mm_thingcolor_monster = "ec ec ec";
			mm_thingcolor_ncmonster = "ec ec ec";
			mm_thingcolor_shootable = "ec ec ec";
			mm_thingcolor_vipitem = "ec ec ec";
			mm_thingcolor_missile = "ec ec ec";
			mm_tswallcolor = "58 5d 56";
			mm_unexploredsecretcolor = 0;
			mm_wallcolor = "4b 32 10";
			mm_yourcolor = "ff ff ff";
			mm_displaylocks = true;
			break;
		default:
			// swwm
			mm_backcolor = "10 10 10";
			mm_cdwallcolor = "30 50 70";
			mm_efwallcolor = "80 a0 c0";
			mm_fdwallcolor = "50 70 90";
			mm_interlevelcolor = "ff 00 60";
			mm_intralevelcolor = "00 60 ff";
			mm_lockedcolor = "00 90 80";
			mm_notseencolor = "20 20 30";
			mm_portalcolor = "40 30 20";
			mm_secretsectorcolor = "80 00 ff";
			mm_secretwallcolor = "60 40 80";
			mm_specialwallcolor = "ff a0 00";
			mm_thingcolor = "ff ff ff";
			mm_thingcolor_citem = "00 ff ff";
			mm_thingcolor_friend = "80 ff a0";
			mm_thingcolor_item = "ff c0 00";
			mm_thingcolor_monster = "ff 60 40";
			mm_thingcolor_ncmonster = "a0 40 20";
			mm_thingcolor_shootable = "ff a0 a0";
			mm_thingcolor_vipitem = "80 60 ff";
			mm_thingcolor_missile = "ff a0 20";
			mm_tswallcolor = "30 20 40";
			mm_unexploredsecretcolor = "40 00 80";
			mm_wallcolor = "c0 e0 ff";
			mm_yourcolor = "80 ff 00";
			mm_displaylocks = true;
			break;
		}
	}
	private bool ShouldDisplaySpecial( int special )
	{
		// thanks graf/randi/whoever
		switch ( special )
		{
		// the following have (max_args < 0)
		// but we can't know this from zscript, so they're hardcoded here
		case Polyobj_StartLine:
		case Polyobj_ExplicitLine:
		case Transfer_WallLight:
		case Sector_Attach3dMidtex:
		case ExtraFloor_LightOnly:
		case Sector_CopyScroller:
		case Scroll_Texture_Left:
		case Scroll_Texture_Right:
		case Scroll_Texture_Up:
		case Scroll_Texture_Down:
		case Plane_Copy:
		case Line_SetIdentification:
		case Line_SetPortal:
		case Sector_Set3DFloor:
		case Sector_SetContents:
		case Plane_Align:
		case Static_Init:
		case Transfer_Heights:
		case Transfer_FloorLight:
		case Transfer_CeilingLight:
		case Scroll_Texture_Model:
		case Scroll_Texture_Offsets:
		case PointPush_SetForce:
			return false;
		}
		return true;
	}
	private bool CheckSectorAction( Sector s, out int special, bool useonly )
	{
		for ( Actor act=s.SecActTarget; act; act=act.tracer )
		{
			if ( (act.Health&(SectorAction.SECSPAC_Use|SectorAction.SECSPAC_UseWall) || !useonly)
				&& act.special && !act.bFRIENDLY )
			{
				special = act.special;
				return true;
			}
		}
		return false;
	}
	private bool RealLineSpecial( Line l, out int special )
	{
		if ( special && l.activation&SPAC_PlayerActivate )
			return true;
		if ( CheckSectorAction(l.frontsector,special,!l.backsector) )
			return true;
		return (l.backsector && CheckSectorAction(l.backsector,special,false));
	}
	private bool ShowTriggerLine( Line l )
	{
		if ( am_showtriggerlines == 0 ) return false;
		int special = l.special;
		if ( !RealLineSpecial(l,special) ) return false;
		if ( !ShouldDisplaySpecial(special) ) return false;
		if ( special && (am_showtriggerlines >= 2) ) return true;
		if ( !special || (special == Door_Open)
			|| (special == Door_Close)
			|| (special == Door_CloseWaitOpen)
			|| (special == Door_Raise)
			|| (special == Door_Animated)
			|| (special == Generic_Door) )
			return false;
		return true;
	}
	private bool CmpFloorPlanes( Line l )
	{
		return (l.frontsector.floorplane.Normal == l.backsector.floorplane.Normal)
			&& (l.frontsector.floorplane.D == l.backsector.floorplane.D);
	}
	private bool CmpCeilingPlanes( Line l )
	{
		return (l.frontsector.ceilingplane.Normal == l.backsector.ceilingplane.Normal)
			&& (l.frontsector.ceilingplane.D == l.backsector.ceilingplane.D);
	}

	private int CheckSecret( Line l )
	{
		if ( !mm_secretsectorcolor || !mm_unexploredsecretcolor )
			return 0;
		if ( l.frontsector && (l.frontsector.flags&Sector.SECF_WASSECRET) )
		{
			if ( am_map_secrets && !(l.frontsector.flags&Sector.SECF_SECRET) ) return 1;
			if ( (am_map_secrets == 2) && !(l.flags&Line.ML_SECRET) ) return 2;
		}
		if ( l.backsector && (l.backsector.flags&Sector.SECF_WASSECRET) )
		{
			if ( am_map_secrets && !(l.backsector.flags&Sector.SECF_SECRET) ) return 1;
			if ( (am_map_secrets == 2) && !(l.flags&Line.ML_SECRET) ) return 2;
		}
		return 0;
	}
	private bool CheckFFBoundary( Line l )
	{
		int fcount = l.frontsector.Get3DFloorCount(),
			bcount = l.backsector.Get3DFloorCount();
		// no 3D floors, no boundary
		if ( !fcount && !bcount ) return false;
		int fvalid = 0, bvalid = 0;
		for ( int i=0; i<fcount; i++ )
		{
			F3DFloor ff = l.frontsector.Get3DFloor(i);
			if ( (ff.flags&F3DFloor.FF_THISINSIDE) || !(ff.flags&F3DFloor.FF_EXISTS) || (ff.alpha == 0) )
				continue;
			fvalid++;
		}
		for ( int i=0; i<bcount; i++ )
		{
			F3DFloor ff = l.backsector.Get3DFloor(i);
			if ( (ff.flags&F3DFloor.FF_THISINSIDE) || !(ff.flags&F3DFloor.FF_EXISTS) || (ff.alpha == 0) )
				continue;
			bvalid++;
		}
		// unmatched counts, there's definitely a boundary
		if ( fvalid != bvalid ) return true;
		for ( int i=0; i<fcount; i++ )
		{
			F3DFloor ff = l.frontsector.Get3DFloor(i);
			if ( (ff.flags&F3DFloor.FF_THISINSIDE) || !(ff.flags&F3DFloor.FF_EXISTS) || (ff.alpha == 0) )
				continue;
			bool found = false;
			for ( int j=0; j<bcount; j++ )
			{
				F3DFloor ff2 = l.backsector.Get3DFloor(i);
				if ( (ff2.flags&F3DFloor.FF_THISINSIDE) || !(ff2.flags&F3DFloor.FF_EXISTS) || (ff2.alpha == 0) )
					continue;
				if ( (ff.model != ff2.model) || (ff.flags != ff2.flags) )
					continue;
				found = true;
				break;
			}
			// at least one mismatch between sectors, there's a boundary for sure
			if ( !found ) return true;
		}
		// no boundary here
		return false;
	}

	private void DrawMapLines( Vector2 basepos )
	{
		double zoomlevel = SWWMUtility.Lerp(oldminimapzoom,minimapzoom,FracTic);
		double zoomview = MAPVIEWDIST*zoomlevel, zoomclip = CLIPDIST*zoomlevel;
		Vector2 cpos = SWWMUtility.LerpVector2(players[consoleplayer].Camera.prev.xy,players[consoleplayer].Camera.pos.xy,FracTic);
		Sector csec = players[consoleplayer].Camera.CurSector;
		int thisgroup = csec.portalgroup;
		int numgroups = level.GetPortalGroupCount();
		// draw overlays first
		for ( int p=numgroups-1; p >= -1; p-- )
		{
			if ( p == thisgroup ) continue;
			foreach ( l : level.lines )
			{
				if ( !(l.flags&Line.ML_MAPPED) && !level.allmap && !am_cheat ) continue;
				if ( (l.flags&Line.ML_DONTDRAW) && ((am_cheat == 0) || (am_cheat >= 4)) )
					continue;
				Vector2 rv1 = l.v1.p-cpos, rv2 = l.v2.p-cpos;
				int lgroup;
				if ( l.sidedef[0].flags&Side.WALLF_POLYOBJ ) lgroup = level.PointInSector(l.v1.p+l.delta/2.).portalgroup;
				else lgroup = l.frontsector.portalgroup;
				bool isportal = ((numgroups>0)&&(lgroup!=thisgroup));
				if ( lgroup == p )
				{
					// portal displacement
					Vector2 pofs = level.GetDisplacement(lgroup,thisgroup);
					rv1 += pofs;
					rv2 += pofs;
				}
				else if ( (p != -1) || (lgroup != thisgroup) )
					continue;
				Vector2 mid = (rv1+rv2)/2.;
				Vector2 siz = (abs(rv1.x-rv2.x),abs(rv1.y-rv2.y))/2.;
				if ( (((siz.x+zoomview)-abs(mid.x)) <= 0) || (((siz.y+zoomview)-abs(mid.y)) <= 0) )
					continue;
				// flip Y
				rv1.y *= -1;
				rv2.y *= -1;
				// rotate by view
				rv1 = Actor.RotateVector(rv1,ViewRot.x-90);
				rv2 = Actor.RotateVector(rv2,ViewRot.x-90);
				// clip to frame
				bool visible;
				[visible, rv1, rv2] = SWWMUtility.LiangBarsky((-1,-1)*zoomclip,(1,1)*zoomclip,rv1,rv2);
				if ( !visible ) continue;
				// scale to minimap frame
				rv1 *= (HALFMAPSIZE/zoomclip)*hs;
				rv2 *= (HALFMAPSIZE/zoomclip)*hs;
				// offset to minimap center
				rv1 += basepos;
				rv2 += basepos;
				// get the line color
				Color col = mm_wallcolor;
				if ( (l.flags&Line.ML_MAPPED) || am_cheat )
				{
					int secwit = CheckSecret(l);
					int lock = SWWMUtility.GetLineLock(l);
					if ( secwit == 1 ) col = mm_secretsectorcolor;
					else if ( secwit == 2 ) col = mm_unexploredsecretcolor;
					else if ( l.flags&Line.ML_SECRET )
					{
						if ( am_cheat && l.backsector && mm_secretwallcolor )
							col = mm_secretwallcolor;
						else col = mm_wallcolor;
					}
					else if ( mm_interlevelcolor
						&& ((l.special == Exit_Normal)
						|| (l.special == Exit_Secret)
						|| (l.special == Teleport_NewMap)
						|| (l.special == Teleport_EndGame)) )
						col = mm_interlevelcolor;
					else if ( mm_intralevelcolor &&
						(l.activation&SPAC_PlayerActivate)
						&& ((l.special == Teleport)
						|| (l.special == Teleport_NoFog)
						|| (l.special == Teleport_ZombieChanger)
						|| (l.special == Teleport_Line)) )
						col = mm_intralevelcolor;
					else if ( mm_displaylocks
						&& (lock > 0) && (lock < 256) )
					{
						let lcol = SWWMUtility.GetLockColor(lock);
						if ( lcol ) col = lcol;
						else col = mm_lockedcolor;
					}
					else if ( mm_specialwallcolor && ShowTriggerLine(l) )
						col = mm_specialwallcolor;
					else if ( l.frontsector && l.backsector )
					{
						if ( !CmpFloorPlanes(l) ) col = mm_fdwallcolor;
						else if ( !CmpCeilingPlanes(l) ) col = mm_cdwallcolor;
						else if ( CheckFFBoundary(l) ) col = mm_efwallcolor;
						else
						{
							if ( (am_cheat == 0) || (am_cheat >= 4) )
								continue;
							col = mm_tswallcolor;
						}
					}
				}
				else col = mm_notseencolor;
				// draw the line
				if ( isportal )
				{
					col = Color((col.r+mm_portalcolor.r*7)/8,(col.g+mm_portalcolor.g*7)/8,(col.b+mm_portalcolor.b*7)/8);
					Screen.DrawThickLine(int(rv1.x),int(rv1.y),int(rv2.x),int(rv2.y),max(1.,hs*.25),col);
				}
				else Screen.DrawThickLine(int(rv1.x),int(rv1.y),int(rv2.x),int(rv2.y),max(1.,hs*.5),col);
			}
		}
	}
	private void DrawMapMarkers( Vector2 basepos )
	{
		double zoomlevel = SWWMUtility.Lerp(oldminimapzoom,minimapzoom,FracTic);
		double zoomview = MAPVIEWDIST*zoomlevel, zoomclip = CLIPDIST*zoomlevel;
		Vector2 cpos = SWWMUtility.LerpVector2(players[consoleplayer].Camera.prev.xy,players[consoleplayer].Camera.pos.xy,FracTic);
		Sector csec = players[consoleplayer].Camera.CurSector;
		if ( !mi ) mi = ThinkerIterator.Create("MapMarker",Thinker.STAT_MAPMARKER);
		else mi.Reinit();
		MapMarker m;
		while ( m = MapMarker(mi.Next()) )
		{
			if ( m.bDORMANT ) continue;
			if ( m.args[1] && !(m.CurSector.moreflags&Sector.SECMF_DRAWN) ) continue;
			TextureID tx;
			if ( m.picnum.IsValid() ) tx = m.picnum;
			else tx = m.CurState.GetSpriteTexture(1);
			Vector2 sz = TexMan.GetScaledSize(tx);
			Vector2 scl;
			// seems to match automap scaling somewhat
			if ( m.Args[2] ) scl = (m.Scale/zoomlevel)*.15;
			else scl = m.Scale*.5;
			sz.x *= scl.x;
			sz.y *= scl.y;
			double radius = max(sz.x,sz.y);	// naive, I know
			if ( m.args[0] )
			{
				// oh bother, this will be dicks
				let ai = level.CreateActorIterator(m.args[0]);
				Actor a;
				while ( a = ai.Next() )
				{
					Vector2 rv = a.pos.xy-cpos;
					bool isportal = false;
					Sector sec = level.PointInSector(a.pos.xy);
					if ( sec.portalgroup != csec.portalgroup )
					{
						isportal = true;
						// portal displacement
						rv += level.GetDisplacement(sec.portalgroup,csec.portalgroup);
					}
					if ( (((radius+zoomview)-abs(rv.x)) <= 0) || (((radius+zoomview)-abs(rv.y)) <= 0) )
						continue;
					// flip Y
					rv.y *= -1;
					// rotate by view
					rv = Actor.RotateVector(rv,ViewRot.x-90);
					// scale to minimap frame
					rv *= (HALFMAPSIZE/zoomclip)*hs;
					// offset to minimap center
					rv += basepos;
					// draw
					Screen.DrawTexture(tx,false,rv.x,rv.y,DTA_ColorOverlay,isportal?Color(128,mm_portalcolor.r,mm_portalcolor.g,mm_portalcolor.b):Color(0,0,0,0),DTA_ScaleX,hs*scl.x,DTA_ScaleY,hs*scl.y,DTA_LegacyRenderStyle,m.GetRenderStyle(),DTA_Alpha,m.Alpha,DTA_FillColor,m.FillColor,DTA_TranslationIndex,m.Translation);
				}
				ai.Destroy();
				continue;
			}
			Vector2 rv = m.pos.xy-cpos;
			bool isportal = false;
			Sector sec = level.PointInSector(m.pos.xy);
			if ( sec.portalgroup != csec.portalgroup )
			{
				isportal = true;
				// portal displacement
				rv += level.GetDisplacement(sec.portalgroup,csec.portalgroup);
			}
			if ( (((radius+zoomview)-abs(rv.x)) <= 0) || (((radius+zoomview)-abs(rv.y)) <= 0) )
				continue;
			// flip Y
			rv.y *= -1;
			// rotate by view
			rv = Actor.RotateVector(rv,ViewRot.x-90);
			// scale to minimap frame
			rv *= (HALFMAPSIZE/zoomclip)*hs;
			// offset to minimap center
			rv += basepos;
			// draw
			Screen.DrawTexture(tx,false,rv.x,rv.y,DTA_ColorOverlay,isportal?Color(128,mm_portalcolor.r,mm_portalcolor.g,mm_portalcolor.b):Color(0,0,0,0),DTA_ScaleX,hs*scl.x,DTA_ScaleY,hs*scl.y,DTA_LegacyRenderStyle,m.GetRenderStyle(),DTA_Alpha,m.Alpha,DTA_FillColor,m.FillColor,DTA_TranslationIndex,m.Translation);
		}
	}
	private void DrawMapThings( Vector2 basepos )
	{
		double zoomlevel = SWWMUtility.Lerp(oldminimapzoom,minimapzoom,FracTic);
		double zoomview = MAPVIEWDIST*zoomlevel, zoomclip = CLIPDIST*zoomlevel;
		Vector2 cpos = SWWMUtility.LerpVector2(players[consoleplayer].Camera.prev.xy,players[consoleplayer].Camera.pos.xy,FracTic);
		Sector csec = players[consoleplayer].Camera.CurSector;
		bool drawmissiles = swwm_mm_missiles;
		for ( SWWMSimpleTracker t=hnd.strackers; t; t=t.next )
		{
			if ( !drawmissiles && t.ismissile ) continue;
			if ( level.allmap && (t.target is 'Key') ) continue;	// don't draw keys over the actual markers they have
			Color col = mm_thingcolor;
			bool isitem = false;
			bool plainactor = false;
			Vector2 pos;
			double angle;
			double radius;
			if ( t.target )
			{
				pos = SWWMUtility.LerpVector2(t.target.prev.xy,t.target.pos.xy,FracTic);
				angle = t.target.angle;
				radius = t.isybeam?(t.target.speed*cos(t.target.pitch-90)):t.isbeam?(t.target.speed*cos(t.target.pitch)):t.target.radius;
			}
			else
			{
				pos = t.pos.xy;
				angle = t.angle;
				radius = t.radius;
			}
			if ( t.isitem )
			{
				if ( t.vipitem ) col = mm_thingcolor_vipitem;
				else if ( t.countitem ) col = mm_thingcolor_citem;
				else col = mm_thingcolor_item;
				isitem = true;
			}
			else if ( t.isplayer ) col = t.playercol;
			else if ( t.friendly ) col = mm_thingcolor_friend;
			else if ( t.countkill ) col = mm_thingcolor_monster;
			else if ( t.ismonster ) col = mm_thingcolor_ncmonster;
			else if ( t.ismissile ) col = mm_thingcolor_missile;
			else
			{
				if ( t.vipitem ) col = mm_thingcolor_vipitem;	// chanceboxes
				else if ( t.shootable ) col = mm_thingcolor_shootable;
				plainactor = true;
			}
			int mtime = GameTicRate;
			if ( level.allmap && !t.expired && t.target ) mtime += GameTicRate*3;
			Vector2 rv = pos-cpos;
			bool isportal = false;
			Sector sec = level.PointInSector(pos);
			if ( sec.portalgroup != csec.portalgroup )
			{
				isportal = true;
				// portal displacement
				rv += level.GetDisplacement(sec.portalgroup,csec.portalgroup);
				// and blend in the color too
				col = Color((col.r+mm_portalcolor.r*7)/8,(col.g+mm_portalcolor.g*7)/8,(col.b+mm_portalcolor.b*7)/8);
			}
			if ( (((radius+zoomview)-abs(rv.x)) <= 0) || (((radius+zoomview)-abs(rv.y)) <= 0) )
				continue;
			Vector2 tv[4];
			int nidx;
			if ( t.isbeam )
			{
				// oriented line
				nidx = 2;
				tv[0] = rv;
				tv[1] = rv+Actor.RotateVector((radius,0),angle);
			}
			else if ( isitem )
			{
				// rhombus
				nidx = 4;
				double crad = min(radius,10);
				for ( int i=0; i<4; i++ )
					tv[i] = rv+Actor.RotateVector((crad,0),i*90);
			}
			else if ( plainactor )
			{
				// aabb box
				nidx = 4;
				tv[0] = rv+(-radius,-radius);
				tv[1] = rv+(radius,-radius);
				tv[2] = rv+(radius,radius);
				tv[3] = rv+(-radius,radius);
			}
			else
			{
				// oriented triangle
				nidx = 3;
				tv[0] = rv+Actor.RotateVector((radius,0),angle);
				tv[1] = rv+Actor.RotateVector((-radius*.5,radius*.7),angle);
				tv[2] = rv+Actor.RotateVector((-radius*.5,-radius*.7),angle);
			}
			// flip Y
			for ( int j=0; j<nidx; j++ ) tv[j].y *= -1;
			// rotate by view
			for ( int j=0; j<nidx; j++ ) tv[j] = Actor.RotateVector(tv[j],ViewRot.x-90);
			bool visible, drawn;
			Vector2 x0, x1;
			// clip to frame
			for ( int j=0; j<nidx; j++ )
			{
				[visible, x0, x1] = SWWMUtility.LiangBarsky((-1,-1)*zoomclip,(1,1)*zoomclip,tv[j],tv[(j+1)%nidx]);
				if ( visible )
				{
					// scale to minimap frame
					x0 *= (HALFMAPSIZE/zoomclip)*hs;
					x1 *= (HALFMAPSIZE/zoomclip)*hs;
					// offset to minimap center
					x0 += basepos;
					x1 += basepos;
					// draw the line
					if ( isportal ) Screen.DrawThickLine(int(x0.x),int(x0.y),int(x1.x),int(x1.y),max(1.,hs*.25),col,int(t.smoothalpha*255));
					else Screen.DrawThickLine(int(x0.x),int(x0.y),int(x1.x),int(x1.y),max(1.,hs*.5),col,int(t.smoothalpha*255));
					drawn = true;
				}
			}
			if ( drawn )
			{
				double alph = clamp(((t.lastupdate+mtime)-level.maptime)/double(GameTicRate),0.,1.);
				if ( t.isbeam ) alph *= t.target?(t.target.alpha/t.target.default.alpha):0.;
				double theta = clamp(5.*FrameTime,0.,1.);
				t.smoothalpha = SWWMUtility.Lerp(t.smoothalpha,alph,theta);
			}
			else t.smoothalpha = 0.;
		}
	}

	private String OrdinalStr( int val, int gender )
	{
		String lstr = "SWWM_PLACE"..val.."_GENDER"..gender;
		String str = StringTable.Localize("$"..lstr);
		if ( str != lstr ) return str;
		return StringTable.Localize("$SWWM_PLACE"..val);
	}

	private void DrawTopStuff()
	{
		int xx, yy = margin;
		// obviously, don't draw the minimap if the automap is open
		if ( !automapactive && swwm_mm_enable )
		{
			GetMinimapColors();
			xx = int(ss.x-(margin+(HALFMAPSIZE+2)*2));
			Screen.DrawTexture(MiniBox,false,xx,yy,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
			Vector2 basemappos = (xx+HALFMAPSIZE+2,yy+HALFMAPSIZE+2);
			Screen.Dim(mm_backcolor,1.,int((basemappos.x-HALFMAPSIZE)*hs),int((basemappos.y-HALFMAPSIZE)*hs),int(HALFMAPSIZE*2*hs),int(HALFMAPSIZE*2*hs));
			Screen.SetClipRect(int((basemappos.x-HALFMAPSIZE)*hs),int((basemappos.y-HALFMAPSIZE)*hs),int(HALFMAPSIZE*2*hs),int(HALFMAPSIZE*2*hs));
			// draw dat stuff
			DrawMapLines(basemappos*hs);
			DrawMapThings(basemappos*hs);
			DrawMapMarkers(basemappos*hs);
			// finally, draw the player arrow
			Vector2 tv[3];
			tv[0] = (0,-4);
			tv[1] = (-3,2);
			tv[2] = (3,2);
			for ( int i=0; i<3; i++ ) tv[i] = (tv[i]+basemappos)*hs;
			for ( int i=0; i<3; i++ ) Screen.DrawThickLine(int(tv[i].x),int(tv[i].y),int(tv[(i+1)%3].x),int(tv[(i+1)%3].y),max(1.,hs*.5),mm_yourcolor);
			Screen.ClearClipRect();
			yy += ((HALFMAPSIZE+2)*2)+5;
		}
		// draw stats and timer when automap is open
		int fstats = swwm_forcestats;
		if ( automapactive || (fstats > 0) )
		{
			xx = int(ss.x-(margin+2));
			String str;
			if ( automapactive || (fstats > 1) )
			{
				int label = am_showmaplabel;
				String ln = level.levelname;
				int iof = ln.IndexOf(" - by: ");
				if ( iof != -1 ) ln.Truncate(iof);
				if ( !label || ((level.clusterflags&level.CLUSTER_HUB) && (label == 2)) ) str = ln;
				else str = String.Format("%s - %s",level.mapname.MakeUpper(),ln);
				Screen.DrawText(mSmallFontOutline,tclabel,xx-mSmallFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				yy += mSmallFontOutline.GetHeight()+4;
			}
			if ( (level.total_monsters > 0) && am_showmonsters && !deathmatch )
			{
				str = String.Format("\c"..tclabel_s.."K \c-%d\c"..tcextra_s.."/\c-%d",level.killed_monsters,level.total_monsters);
				Screen.DrawText(MiniHUDFontOutline,(level.killed_monsters>=level.total_monsters)?tccompl:tcvalue,xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				if ( killflash && (gametic < killflash) )
				{
					double alph = max((killflash-(gametic+FracTic))/25.,0.)**1.5;
					str = String.Format("%d/%d",level.killed_monsters,level.total_monsters);
					int slashpos = str.IndexOf("/");
					Screen.DrawText(MiniHUDFontOutline,mhudfontcol[MCR_FLASH],xx-MiniHUDFontOutline.StringWidth(str),yy,str.Left(slashpos),DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				}
				if ( tkillflash && (gametic < tkillflash) )
				{
					double alph = max((tkillflash-(gametic+FracTic))/25.,0.)**1.5;
					str = String.Format("%d",level.total_monsters);
					Screen.DrawText(MiniHUDFontOutline,mhudfontcol[MCR_FLASH],xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				}
				yy += MiniHUDFontOutline.GetHeight()+2;
			}
			if ( (level.total_items > 0) && am_showitems && !deathmatch )
			{
				str = String.Format("\c"..tclabel_s.."I \c-%d\c"..tcextra_s.."/\c-%d",level.found_items,level.total_items);
				Screen.DrawText(MiniHUDFontOutline,(level.found_items>=level.total_items)?tccompl:tcvalue,xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				if ( itemflash && (gametic < itemflash) )
				{
					double alph = max((itemflash-(gametic+FracTic))/25.,0.)**1.5;
					str = String.Format("%d/%d",level.found_items,level.total_items);
					int slashpos = str.IndexOf("/");
					Screen.DrawText(MiniHUDFontOutline,mhudfontcol[MCR_FLASH],xx-MiniHUDFontOutline.StringWidth(str),yy,str.Left(slashpos),DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				}
				if ( titemflash && (gametic < titemflash) )
				{
					double alph = max((titemflash-(gametic+FracTic))/25.,0.)**1.5;
					str = String.Format("%d",level.total_items);
					Screen.DrawText(MiniHUDFontOutline,mhudfontcol[MCR_FLASH],xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				}
				yy += MiniHUDFontOutline.GetHeight()+2;
			}
			if ( (level.total_secrets > 0) && am_showsecrets && !deathmatch )
			{
				str = String.Format("\c"..tclabel_s.."S \c-%d\c"..tcextra_s.."/\c-%d",level.found_secrets,level.total_secrets);
				Screen.DrawText(MiniHUDFontOutline,(level.found_secrets>=level.total_secrets)?tccompl:tcvalue,xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				if ( secretflash && (gametic < secretflash) )
				{
					double alph = max((secretflash-(gametic+FracTic))/25.,0.)**1.5;
					str = String.Format("%d/%d",level.found_secrets,level.total_secrets);
					int slashpos = str.IndexOf("/");
					Screen.DrawText(MiniHUDFontOutline,mhudfontcol[MCR_FLASH],xx-MiniHUDFontOutline.StringWidth(str),yy,str.Left(slashpos),DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				}
				if ( tsecretflash && (gametic < tsecretflash) )
				{
					double alph = max((tsecretflash-(gametic+FracTic))/25.,0.)**1.5;
					str = String.Format("%d",level.total_secrets);
					Screen.DrawText(MiniHUDFontOutline,mhudfontcol[MCR_FLASH],xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				}
				yy += MiniHUDFontOutline.GetHeight()+2;
			}
			int sec;
			if ( am_showtime )
			{
				sec = Thinker.Tics2Seconds(level.maptime);
				str = String.Format("\c"..tclabel_s.."T \c-%02d\c"..tcextra_s..":\c-%02d\c"..tcextra_s..":\c-%02d",sec/3600,(sec%3600)/60,sec%60);
				Screen.DrawText(MiniHUDFontOutline,((level.sucktime>0)&&(sec>=(level.sucktime*3600)))?tcsucks:((level.partime>0)&&(sec<=level.partime))?tccompl:tcvalue,xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				yy += MiniHUDFontOutline.GetHeight()+2;
			}
			// don't show total time if it's equal to map time
			if ( am_showtotaltime && (level.totaltime != level.maptime) )
			{
				sec = Thinker.Tics2Seconds(level.totaltime);
				str = String.Format("\c"..tclabel_s.."TT \c-%02d\c"..tcextra_s..":\c-%02d\c"..tcextra_s..":\c-%02d",sec/3600,(sec%3600)/60,sec%60);
				Screen.DrawText(MiniHUDFontOutline,tcvalue,xx-MiniHUDFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				yy += MiniHUDFontOutline.GetHeight()+2;
			}
			yy += 3;
		}
		if ( deathmatch )
		{
			yy += 9;
			if ( playercount <= 1 ) return;
			xx = int(ss.x-(margin+2));
			String str;
			if ( teamplay )
			{
				// draw team scores
				for ( int i=0; i<teamscore.Size(); i++ )
				{
					if ( !teamactive[i] ) continue;
					str = String.Format("\c[MiniDemoBlue]%s \c-%d",Teams[i].mName,teamscore[i]);
					Screen.DrawText(mSmallFontOutline,mhudfontcol[MCR_WHITE],xx-mSmallFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
					yy += mSmallFont.GetHeight();
				}
			}
			else
			{
				// draw rank and spread like in UT
				if ( tiedscore ) str = String.Format("\cy%s \c[MiniRed]%d\c[MiniSayaHUD]/\c[MiniRed]%d\c-",StringTable.Localize("$SWWM_DMRANK"),rank,playercount);
				else str = String.Format("\c[MiniDemoBlue]%s \c-%d\c[MiniIbukiHUD]/\c-%d",StringTable.Localize("$SWWM_DMRANK"),rank,playercount);
				Screen.DrawText(mSmallFontOutline,mhudfontcol[MCR_WHITE],xx-mSmallFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				yy += mSmallFont.GetHeight();
				if ( lead > 0 ) str = String.Format("\c[MiniDemoBlue]%s \c-+%d",StringTable.Localize("$SWWM_DMSPREAD"),lead);
				else str = String.Format("\c[MiniDemoBlue]%s \c-%d",StringTable.Localize("$SWWM_DMSPREAD"),lead);
				Screen.DrawText(mSmallFontOutline,mhudfontcol[MCR_RED],xx-mSmallFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
				yy += mSmallFont.GetHeight()+3;
				// draw top 3 players
				for ( int i=0; i<min(3,playercount); i++ )
				{
					if ( sortplayers[i].fragcount < 0 ) str = String.Format("\c[MiniDemoBlue]#%d: \c-%s\c- \c[MiniSayaHUD](\c[MiniRed]%d\c[MiniSayaHUD])\c-",i+1,sortplayers[i].GetUserName(),sortplayers[i].fragcount);
					else str = String.Format("\c[MiniDemoBlue]%s: \c-%s\c- \c[MiniIbukiHUD](\c[MiniWhite]%d\c[MiniIbukiHUD])\c-",OrdinalStr(i+1,sortplayers[i].GetGender()),sortplayers[i].GetUserName(),sortplayers[i].fragcount);
					Screen.DrawText(mSmallFontOutline,mhudfontcol[MCR_WHITE],xx-mSmallFontOutline.StringWidth(str),yy,str,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true);
					yy += mSmallFont.GetHeight();
				}
			}
			return;
		}
		// draw key icons
		Vector2 keypos = (ss.x-(margin+2),yy);
		int colc = 0;
		double colh = 0;
		int n = Key.GetKeyTypeCount();
		Array<Key> klist;
		for ( int i=0; i<n; i++ )
		{
			let k = Key(CPlayer.mo.FindInventory(Key.GetKeyType(i)));
			if ( !k || !k.Icon.IsValid() ) continue;
			klist.Push(k);
		}
		int maxcolc = (gameinfo.gametype&GAME_DOOMCHEX)?6:4;
		foreach ( k:klist )
		{
			// Hexen key icons aren't meant for this kind of HUD
			TextureID icon = (k is 'HexenKey')?k.SpawnState.GetSpriteTexture(0):k.Icon;
			Vector2 siz = TexMan.GetScaledSize(icon);
			Screen.DrawTexture(icon,false,keypos.x-siz.x,keypos.y,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_TopLeft,true);
			foreach ( f:keyflash )
			{
				if ( !(k is f.got) ) continue;
				if ( !f.flashtime || (gametic >= f.flashtime) ) continue;
				double alph = max((f.flashtime-(gametic+FracTic))/25.,0.)**1.5;
				Screen.DrawTexture(icon,false,keypos.x-siz.x,keypos.y,DTA_VirtualWidthF,ss.x,DTA_VirtualHeightF,ss.y,DTA_KeepRatio,true,DTA_TopLeft,true,DTA_ColorOverlay,0xFFFFC040,DTA_LegacyRenderStyle,STYLE_Add,DTA_Alpha,alph);
				break;
			}
			keypos.x -= siz.x+2;
			colh = max(colh,siz.y);
			if ( ++colc == maxcolc )
			{
				keypos.x = ss.x-(margin+2);
				keypos.y += colh+2;
				colh = colc = 0;
			}
		}
	}

	override void DrawAutomapHUD( double ticFrac )
	{
		// do nothing, DrawTopStuff handles this
	}
}